【数据分析】Excel中使用VBA进行宏编程

microsoft excel是广泛用于数据处理和分析的工具，而vba（visual basic for applications）是一种基于microsoft visual basic的编程语言，可用于在excel中创建自定义宏和自动化任务，控制excel工作簿、工作表和数据，执行各种操作。这篇博客将介绍如何使用vba进行excel宏编程，以提高工作效率和自动化重复任务。

0 准备工作

1. excel中主选项卡默认是没有开发工具选项的，需要选择主选项卡文件→选项→自定义功能区，打开excel中的开发工具面板：
   
   这样，在excel的主选项卡中就有开发工具选项了：
   

2. 在开发工具选项卡中选择visual basic，进入vba编辑器（或使用快捷键alt+f11）：
   

3. 创建新的模块（module）并开始编写第一个宏：
   

4. 如，在excel中显示消息框：

   sub 显示消息框()
       msgbox "欢迎使用vba宏编程！"
   end sub
   

   

5. 编写完成后，保存，使用f5运行或者在开发工具选项卡中选择“运行”来执行宏：
   

6. 运行结果：
   

1 vba简介

1.1 excel vba应用程序的构成

从开发者角度看，excel vba应用程序由工作表、用户窗体、模块和类模块等部分构成。

• 工作表：用于保存和显示程序的数据，是程序的主体部分。一般先在工作表中制作出特定表格的格式，并设置好样式，再通过vba代码获取表格中的数据，经过加工处理后将其填写入相应的单元格，供用户进行查看、打印输出等操作。
• 用户窗体：在excel vba应用程序中，除了可使用工作表与用户进行交互外，还可向程序添加用户窗体，用来与用户进行交互操作。使用用户窗体可将用户与工作表中的数据进行隔离，防止数据被意外修改并隐藏工作表中的敏感数据，使限制权限的用户只看到应该操作的数据。
• 模块：在模块中可保存程序的通用过程，供其他过程调用。例如录制宏的代码就保存在模块中。
• 类模块：在excel vba中，除了可使用系统提供的对象外，还可通过自定义类来创建自定义的对象，自定义的类必须保存在“类模块”中。大多数应用程序都不使用“类模块”。

1.2 事件驱动

vba 是运行在 microsoft office 软件之上，包括 excel、word、ppt、outlook 等，可以用来编写非软件自带的功能的编程语言，不同的是每一个软件具有自己独有的对象，例如 excel 有单元格对象，word 有段落对象，ppt 有幻灯片对象。

office 软件提供丰富的功能接口，vba 可以调用它们，实现自定义的需求。基本上，能用鼠标和键盘能做的事情，vba 都能做，它采用了与windows相似的事件驱动编程方式。

在这种模式下，windows监视窗口活动或事件信号，这些事件可以是用户鼠标点击或按键操作，也可以是程序控制或其他窗口的操作引发的。通过vba的事件驱动机制，开发人员可以编写事件过程来处理系统产生的事件，实现特定的功能，如在鼠标点击时打开一个窗口。

与传统的过程化应用程序不同，事件驱动的应用程序中，代码执行路径不是按照预定顺序进行的。相反，代码在响应不同事件时执行不同的片段。这些事件可以由用户、操作系统、其他应用程序的消息触发，甚至是应用程序自身的消息触发。

由于事件顺序无法预测，代码必须对各种执行状态做出假设。为确保这些假设在执行时有效，应用程序的结构需要组织良好。在excel中使用vba开发应用程序实质上是编写处理各对象不同事件的代码。

1.3 宏

简单的说，宏就是一段可以运行的 vba 代码片段。excel宏使用vba语言进行编写，通过vba编写的宏可控制excel，对excel的功能进行扩充。

1.3.1 创建宏

excel提供了两种创建宏的方法：一种方法是利用excel操作环境中的宏录制器录制用户的操作；另一种方法是使用visual basic编辑器编写自己的宏代码。

利用宏录制器可记录用户在excel中的操作动作，以便自动创建需要的宏，这在不太了解宏命令时是非常方便的。

使用visual basic编辑器可以打开已录制的宏，修改其中的命令，也可以在visual basic编辑器中直接输入命令创建宏。对于很多无法录制的命令（如创建新的窗体等），使用visual basic编辑器创建宏是唯一的方法。

启用录制宏的两种方式：

注：宏名不但可以包含字母、数字和下画线，还可以使用中文，但不能包含空格。但名称开头需为字母或下划线，且不能与已有宏重名。

注：在宏中定义的快捷键将覆盖任何对等的默认的excel快捷键。

在创建宏之后，可以将宏分配给对象（如按钮、图形、控件和快捷键等），这样执行宏就像单击按钮或按快捷键一样简单。正是由于这种操作方便的特性，使用宏可以方便地扩展excel的功能。如果不再需要使用宏，可以将其删除。

如果将录制的宏名称设置为“auto_open”，则每次打开包含此宏的工作簿时，该宏都会运行。另一种在打开工作簿时自动运行宏的方法是使用visual basic编辑器（vbe）在工作簿的open事件中编写vba过程。open事件是一个内置的工作簿事件，它会在每次打开该工作簿时都运行自己的宏代码。如在用户打开工作簿时显示一个“欢迎”对话框，可新建一个模块，在其中输入以下代码：

        sub auto_open()
          msgbox ("欢迎使用excel!")
        end sub

保存并关闭该文件，若提示不能保存，则选择“否”后，将文件保存为.xlsm类型即可。

再次打开该文件时，将会显示“欢迎使用excel！”的对话框。

1.3.2 宏安全

从office软件支持宏开始，宏病毒也随之出现。许多病毒经过专门设计，可以利用vba宏对系统和数据文件进行恶意操作。因此，宏的安全性越来越受到用户的重视。

按照如下步骤设置宏安全性：

1. excel选项卡选择文件→选项→信任中心或者选项卡选择开发工具→宏安全：
   
2. 设置宏的安全性为禁用所有宏，并发出通知：
   
   四种类型的宏设置：

• “禁用所有宏，并且不通知”：如果不信任宏，则使用此设置。文档中的所有宏及有关宏的安全警报都被禁用。如果文档具有信任的未签名的宏，则可以将这些文档放在受信任的位置上。受信任的位置中的文档可直接运行，不会由信任中心安全系统进行检查。
• “禁用所有宏，并发出通知”：这是默认设置。如果想禁用宏，但又希望在存在宏时收到安全警报，则应使用此选项。这样，可以根据具体情况选择何时启用这些宏。
• “禁用无数字签署的所有宏”：此设置与“禁用所有宏，并发出通知”选项相同。但下面这种情况除外：在宏已由受信任的发行者进行了数字签名时，如果信任发行者，则可以运行宏；如果不信任发行者，将发出通知。这样，可以选择启用那些签名的宏或信任发行者的宏。所有未签名的宏都被禁用，且不发出通知。
• “启用所有宏（不推荐，可能会运行有潜在危险的代码）”：可以暂时使用此设置，以便允许运行所有宏。因为此设置容易使计算机受到恶意代码的攻击，所以不建议永久使用此设置。

2 vba基础

2.1 注释

vba 中的注释以英文单引号 ' 开头，后面接注释的内容。从单引号开始的部分不会被执行。

'我是一行注释

2.2 数据类型

excel单元格中可以保存处理多种类型的数据，包括数值、日期/时间、文本、货币等。vba中除了提供这些数据类型之外，还提供字节、布尔和变体数据等类型。

2.2.1 基本数据类型

常见的vba基本数据类型如下表：

数据类型	含义	精度范围
byte	字节型	0 ~ 255
integer	整型	-32,768 ~ 32,767
long	长整型	-2,147,483,648 ~ 2,147,483,647
string	字符串	变长字符串：0 ~ 20亿(231)个字符 定长字符串：1~约64k(216)个字符
single	单精度浮点型	在表示负数时： -3.402823e38 ~ -1.401298e-45 在表示正数时： 1.401298e-45 ~ 3.402823e38
double	双精度浮点型	在表示负数时： -1.79769313486231e308 ~ -4.94065645841247e-324 在表示正数时： 4.94065645841247e-324 ~ 1.79769313486231e308
decimal	定点数	未放置定点数： +/- 79,228,162,514,264,337,593,543,950,335 放置定点数： +/- 7.9228162514264337593543950335
currency	货币型	-922,337,203,685,477.5808 ~ 922,337,203,685,477.5807
date	日期型	时间：00:00:00 至 23:59:59 日期： 100-1-1 至 9999-12-31
boolean	逻辑值	true 或 false
variant	变体型	不限
object	对象型	vba 和 excel 对象

2.2.2 枚举类型

枚举就是将变量的值逐一列举出来，属于该枚举型的变量只能取列举的某一个值。当一个变量只有几种可能的值时，可以定义为枚举类型（enum）。

枚举型举例：

public enum workdays
    星期日
    星期一
    星期二
    星期三
    星期四
    星期五
    星期六
end enum

2.2.3 用户自定义数据类型

在vba中，还可以使用type语句定义自己的数据类型，其格式如下：

type 数据类型名
    数据类型元素名 as 数据类型
    数据类型元素名 as 数据类型
    ...
end type

注，自定义数据类型的定义必须放在模块（模块和类模块）的声明部分中。在使用记录类型之前，必须用type语句进行定义。一般情况下，记录类型在模块中定义，其变量可以出现在工程的任何地方。

2.2 变量

变量是存储数据的一种表达方式。在程序开始，可以声明一个变量，指定变量的类型（数字、文本、逻辑值等），并给变量赋值。在程序的其他地方，就可以使用该变量，用其存储的值参与运算。

2.2.1 声明变量

使用变量前需要先声明变量，即通过以下格式指定变量名和变量的数据类型：

dim [变量名] as [数据类型]

2.2.2 命名变量

在vba中，变量名称为标识符，定义标识符名称时应遵循以下规则：

• 第一个字符必须使用英文字母（中文版excel支持中文字符作标识符名称）。
• 不能在标识符中使用空格、句点（.）、感叹号（!），或者@、&、$、#等字符。
• 标识符的长度不能超过255个字符。
• 通常，标识符不能与vba本身的function过程、语句及方法的名称相同。必须谨慎使用与程序语言的关键字相同的名称。若所使用的内在语言函数、语句或方法与所指定的名称相冲突，则必须显式地识别它。一般会在内置函数、语句或方法的名称之前加上关联的类型库的名称。例如，如果有一个名为left的变量，则只能用vba.left来调用left函数。
• 不能在同一范围的相同层次中使用重复的名称。例如，不能在同一过程中声明两个命名为age的变量。但可以在同一模块中声明一个私有的命名为age的变量和过程级别的命名为age的变量。

在实际开发过程，建议按驼峰法命名。即第一个单词以小写字母开始；从第二个单词开始以后的每个单词的首字母都采用大写字母。如：myfirstname、mylastname。

2.3 常量

在程序运行过程中值不发生变化的量称为常数（又称常量），常数的值在程序执行之前就已经确定，执行过程中不能改变。由于其值的数据类型不同，常量也具有数据类型。vba中常量的类型有三种，分别是直接常数、符号常数和系统常数。

2.3.1 直接常数

在vba程序代码中直接书写的量称为直接常数，如：

area = r * r * 3.14

上述代码中的数值3.14就是直接常数。

直接常数也有数据类型的区别，其数据类型由它本身所表示的数据形式决定。根据数据类型的不同，直接常数分为数值常数、字符串常数、日期/时间常数和布尔常数。

• 数值常数：数值常数是由数字、小数点和正负符号所构成的量。一个数值常数有时可能存在多种数据类型的解释。例如6.18可解释为单精度型，也可为双精度型。vba将使用占用内存少的那种类型，即单精度型。
• 字符串常数：字符串常数是由数字、英文字母、特殊符号和汉字等可见字符构成的，在书写时必须使用双引号作定界符，如："vba"。如果字符串常数中包含双引号，则需要在有双引号的地方输入两次双引号，如："milko说:""vba程序很简单!"""注意最后用了3个双引号，前2个双引号将输出为一个引号，最后1个双引号为字符串的定界符。
• 日期/时间常数：日期/时间常数用来表示某一天或某一具体时间，使用#作为定界符，日期时间的意义要正确，例如#8/8/2008#是正确的，而#2/30/2008#是错误的，因为二月份没有30日。
• 布尔常数：布尔常数也称为逻辑常数，只有两个值：true（真），false（假）。

2.3.2 符号常数

如果在程序中需反复地使用某一个常数，可为该常数命名，在需要使用该常数的地方引用其常数名则可。

使用符号常数有如下优点：

• 提高程序可读性。符号常数是有意义的名字，可提高程序的可读性。
• 快速修改程序。如果需要在程序中修改常数的具体值，只需要在定义符号常数处修改即可。
• 减少出错率。如果反复在程序中输入同一数据，有可能在某处输入错误，导致计算结果不同，不好查错。使用符号常数则只需要定义一次就可引用。

在程序运行时，不能对符号常数进行赋值和修改，因此符号常数在程序运行前必须有确定的值。

声明符号常数与声明变量类似，需要指明符号常数名和数据类型。不同在于，符号常数的值在声明时就需要指定。

声明符号常数的格式如下：

const [常量名] as [数据类型] = [值]

2.3.3 系统常数

系统常数就是vba系统内部提供的一系列各种不同用途的符号常数。例如，色彩常数用“vbblack”表示黑色，比用数值“0x0”更直观易用。这些常数可与应用程序的对象、方法和属性一起使用。

在vba中，系统常数名采用大小写混合的格式，其前缀表示定义常数的对象库名。在excel中的系统常数名通常都是以小写的xl（如xlwindowtype的成员包括xlworkbook等几个）作为前缀，而vb中的系统常数名通常都是以小写的vb作为前缀。要查询某个系统常数的具体名称及其确切值，可通过视图→对象浏览器查询。

2.4 运算符

运算符是介于操作数间的运算符号，vba 中运算符可以分为赋值运算符、算术运算符、比较运算符、逻辑运算符、连接运算符和其他运算符这 6 类。

2.4.1 赋值运算符

给变量赋值会使用到赋值运算符，语法如下：

[变量名] = [数据]

赋值语法核心是=(赋值运算符)，它是右结合的，阅读时从右至左阅读时从右至左，即将数据的值赋值给变量。

其中，[数据]的形式可以是直接书写的内容，例如 4、“好”、true等；也可以是另外一个变量。

变量赋值完成后，在后续的程序中，就可以使用变量参与各类的计算了。

2.4.2 算术运算符

算数运算符即常用的数学运算符，包括加减乘除等。

vba 中的算术运算符如下表所示。

算术运算符	含义
+	两数相加
-	两数相减 或 表示数值表达式的负值
*	两数相乘
/	两数相除
\	两数相除，取整
mod	两数相除，取余
^	幂运算

2.4.3 比较运算符

比较运算符用来表示两个或多个值或表达式之间的关系，比较结果只能为true或false。

vba 中的比较运算符如下表所示。

比较运算符	含义
=	比较两个值是否相等
>	大于
>=	大于等于
<	小于
<=	小于等于
<>	不等于

2.4.4 逻辑运算符

逻辑运算符是指连接表达式进行逻辑运算的运算符，逻辑运算结果只有true和false两种可能。

逻辑运算符	含义
and	逻辑与，若两个表达式都为真，则返回 true
or	逻辑或，若两个表达式至少有一个为真，则返回 true
not	逻辑非，对逻辑表达式取否
xor	逻辑异或，若两个表达式不相同，则返回 true
eqv	逻辑等价，若两个表达式两在逻辑上等效，则返回 true
imp	逻辑蕴含，若第一个表达式蕴含第二个表达式，则返回 true

2.4.5 连接运算符

vba 中的连接运算符用于连接 2 个或多个文本。

连接运算符	含义
&	强制两个表达式做字符串连接。如果表达式的结果不是字符串，则将其转换成字符串
+	用于两个字符串的连接，只有运算符两边的表达式都是字符串时才进行连接运算

注：在使用“+”运算符时有可能无法确定是做加法还是做字符串连接。因此，为避免混淆，一般使用“&”运算符进行连接。

2.4.6 其他运算符

其他运算符	含义
_	将一行代码分解成两行
:	将两行代码放置在一行

2.5 常用语句

2.5.1 语句

一行代码就是一条语句。在默认情况下，在vba编辑器中输入语句后，vba编辑器将自动进行语法检查。

2.5.1.1 自动格式化

输入vba语句后，vba编辑器将按一定的规则进行简单的格式化处理。例如将关键字的首字母大写，在运算符前后加入空格，删除各部分多余的空格等。

在输入vba关键字时，可以不区分大小写。例如，输入msgbox时，无论输入的是msgbox、msgbox还是msgbox，当输入完该函数的参数并按回车键后，vba编辑器会自动将其变为msgbox。

为了提高程序的可读性，vba代码中应加上适当的空格。当按回车键完成语句的输入后，各关键字之间无论插入多少空格，vba编辑器都将其自动调整为一个空格。

2.5.1.2 复合语句

一般情况下，要求程序中每个语句占一行。但在vba中，也可以把几个语句放在一行中构成复合语句。复合语句中各语句之间用冒号（:）分隔，例如：

	selection.font.bold = true: selection.font.size = 20

与以下两个语句的功能相同：

   selection.font.bold = true
   selection.font.size = 20

2.5.1.3 语句断行

在vba编辑器的代码窗口中，每行vba代码可包含1023个字符。但是，为了使程序便于阅读，建议读者将一条长的语句打断为若干行。vba中使用空格后接着一个下画线——续行符，可将一行代码延伸成两行以上。例如以下语句：

	activeworkbook.protect password:=" abc ", structure:=true, windows:=false

等价于

    activeworkbook.protect _
                  password:="abc", _
                  structure:=true, _
                  windows:=false

通过续行符_可创建长的逻辑行。一个逻辑行，最多可包含24个连续的续行字符，也就是最多可以包含25个物理行。这样，逻辑行的字符总量可达10230字符。如果超过了字符总量，必须将该行分为若干语句或指定一些表达式为中间变量。

2.5.2 输入/输出语句

计算机程序一般分为三部分：首先接收用户输入的数据；再按一定的算法对数据进行加工处理；最后输出程序处理的结果。在程序中，输入/输出语句占有很大的比例。在excel中，可从工作表、用户窗体等多处获取数据，并可将数据输出到这些对象中。数据输入/输出的相关内容将在后续章节中进行介绍，本节主要介绍vba中标准的输入/输出方法。

2.5.2.1 输入语句

为了实现数据输入，vba提供了inputbox函数。该函数将打开一个对话框作为输入数据的界面，等待用户输入数据，并返回所输入的内容。语法格式如下：

	inputbox(prompt[,title][,default][,xpos][,ypos][,helpfile,context])

其中，inputbox函数的7个参数意义分别如下：

• prompt：对话框消息出现的字符串表达式，最大长度为1 024个字符。如果需要在对话框中显示多行数据，则可在各行之间用回车换行符来分隔，一般使用vba的常数vbcrlf代表回车换行符。
• title：对话框标题栏中的字符串。如果省略该参数，则把应用程序名放入标题栏中。
• default：显示在文本框中的字符串。如果省略该参数，则文本框为空。
• xpos（和ypos成对出现）：指定对话框的左边与屏幕左边的水平距离。如果省略该参数，则对话框会在水平方向居中。
• ypos（和xpos成对出现）：指定对话框的上边与屏幕上边的距离。如果省略该参数，则对话框被放置在屏幕垂直方向距下边界大约三分之一的位置。
• helpfile：设置对话框的帮助文件，可省略。
• context：设置对话框的帮助主题编号，可省略。

例如，接收用户的输入示例如下：

	sub 使用inputbox函数()
	  dim strprompt as string
	  dim strtitle as string
	  dim strdefault as string
	  dim strreturn as string
	  strprompt = "请输入用户姓名："
	  strtitle = "输入对话框"
	  strdefault = "milko"
	  strreturn = inputbox(strprompt, strtitle, strdefault)
	  debug.print strreturn
	end sub

运行上述代码，会弹出如下的对话框：

在文本框中输入新的姓名，单击“确定”按钮，程序将把用户输入的内容输出到“立即窗口”中。

使用inputbox函数时，需注意：

• 在默认情况下，inputbox函数的返回值是一个字符串类型，而不是变体类型。如果需要使用该函数输入数值，则需要使用val函数（或其他的转换函数）将返回值转换为相应类型的数值。
• 如果用户单击“取消”按钮（或按“esc”键），则表示不使用当前输入的值，函数将返回一个空字符串。根据这一特性，可以判断用户是否把数据输入到对话框中。
• 执行一次inputbox函数，只能返回一个值，如果需要输入多个值，则必须多次调用该函数。

2.5.2.2 输出语句

1.print方法

上述接收用户输入的代码中用到了print方法用于输出信息，信息将被输出到“立即窗口”（视图→立即窗口或使用快捷键ctrl+g）中。

print方法的语法如下：

	object.print [outputlist]

在vba中，object只能为debug对象，表示向“立即窗口”输出内容。

参数outputlist是要打印的表达式或表达式的列表。如果省略，则打印一个空白行。

print首先计算表达式的值，然后输出计算的结果。在outputlist参数中还可以使用分隔符以格式化输出的数据。格式化分隔符有以下4种。

• spc(n)：插入n个空格到输出数据之间。
• tab(n)：移动光标到适当位置，n为移动的列数。
• 分号：表示前后两个数据项连在一起输出。
• 逗号：以14个字符为一个输出区，每个数据输出到对应的输出区。

2.msgbox函数

使用msgbox函数可打开一个对话框，在对话框中显示一个提示信息，并让用户单击对话框中的按钮，使程序继续执行。msgbox有语句和函数两种格式，语句格式如下：

	msgbox prompt[,buttons][,title][,helpfile,context]

函数格式如下：

	value=msgbox(prompt[,buttons][,title][ ,helpfile,context])

通过函数返回值获得用户单击的按钮，并可根据按钮的不同而选择不同的程序段来执行。

该函数（或语句）共有5个参数，除第一个参数是对话框展示的提示外，其余参数都可省略。各参数的意义与inputbox函数参数的意义相同，不同的是多了一个buttons参数。buttons参数用来指定显示按钮的数目及形式、使用提示图标样式、默认按钮，以及消息框的强制响应等。其常数值如下表所示。

常量	值	说明
vbokonly	0	只显示“确定”(ok)按钮
vbokcancel	1	显示“确定”(ok)及“取消”(cancel)按钮
vbabortretrylgnore	2	显示“异常终止”(abort)、“重试”(retry)及“忽略”(ignore)按钮
vbyesnocancel	3	显示“是”(yes)“否”(no)及“取消”(cancel)按钮
vbyesno	4	显示“是”(yes)及“否”(no)按钮
vbretrycancel	5	显示“重试”(retry)及“取消”(cancel)按钮
vbcritical	16	显示criticalmessage图标
vbquestion	32	显示warningquery图标
vbexclamation	48	显示warningmessage图标
vbinformation	64	显示informationmessage图标
vbdefaultbutton1	0	以第一个按钮为默认按钮
vbdefaultbutton2	256	以第二个按钮为默认按钮
vbdefaultbutton3	512	以第三个按钮为默认按钮
vbdefaultbutton4	768	以第四个按钮为默认按钮
vbapplicationmodal	0	进入该消息框，当前应用程序暂停
vbsystemmodal	4096	进入该消息框，所有应用程序暂停

表中的数值（或常数）可分为4组：

• 第一组值（0～5）：决定对话框中按钮的类型与数量。
• 第二组值（16，32，48，64）：决定对话框中显示的图标。
• 第三组值（0，256，512，768）：设置对话框的默认活动按钮。活动按钮中文字的周围有虚线，按“enter”键可执行该按钮的单击事件代码。
• 第四组值（0，4096）：决定消息框的强制响应性。

buttons参数可由上面4组数值组成，其组成原则是：从每一类中选择一个值，把这几个值累加在一起就是buttons参数的值（大部分时间里都只使用前三组数值的组合），不同的组合可得到不同的结果。

如询问用户是否退出系统：

    sub 使用msgbox函数退出系统()
      dim intreturn as integer
      intreturn = msgbox("真的退出系统吗？", vbyesno + vbquestion, "提示")
      if intreturn = vbyes then application.quit
    end sub

运行以上代码，会弹出如下对话框：

如果用户单击“是”按钮，将执行quit方法退出excel；如果用户单击“否”按钮，将返回应用程序。

2.5.3 暂停/退出语句

程序在运行过程中，如果需要查看变量的运算中间值，可在代码中加入暂停语句，使程序暂停运行，然后在立即窗口中查看各变量的值。当满足一定条件时，可使用退出语句结束程序的运行。

2.5.3.1 暂停语句

在需要暂停程序执行的地方放置stop语句，即可让程序暂停运行。用stop语句，就相当于在程序代码中设置断点。

stop语句会暂停程序的执行，但是它不像end语句，因为stop不会关闭任何文件或清除变量。暂停的程序又可以接着执行后续的代码。

stop语句主要用在调试程序阶段，在应用程序发布之前需要将程序中的stop语句删除或注释掉。

下面的代码使用stop语句来暂停“for…next”循环里的每一次完成。

    sub 暂停程序的执行()
      dim i as integer
      for i = 1 to 10           '开始for...next循环
          debug.print i          '将变量i的值输出到“立即”窗口
          stop                   '每一次的完成都会在此暂停
      next
    end sub

运行以上代码，每点击一次“运行”按钮，立即窗口都会显示一个递增的值：

2.5.3.2 退出语句

所谓的“退出”有两种意义，一是退出正在执行的vba代码，返回到vba的编辑环境中；另一种是退出excel系统。

1.end语句

使用end语句可结束程序的运行，返回到vba的编辑环境中。执行end语句会重置所有模块级别变量和所有模块的静态局部变量。若要保留这些变量的值，需改为使用stop语句，可以在保留这些变量值的基础上恢复执行。

end语句提供了一种强迫终止程序的方法。vba程序正常结束应该卸载所有的窗体。只要没有其他程序引用该程序公共类模块创建的对象并且无代码执行，程序将立即关闭。

注：end语句只是强制性地终止代码执行，窗体和类模块中的unload、queryunload和terminate事件代码并未被执行。同时，类模块创建的对象被破坏，由open语句打开的文件被关闭，并且释放程序所占用的内存。其他程序的对象引用无效。

2.quit方法

使用application对象的quit方法，将退出excel：

application.quit

使用此方法时，如果未保存的工作簿处于打开状态，则excel将显示一个对话框，询问是否要保存所作更改。

2.6 程序结构

程序结构表示程序的运行方式。vba 正是因为存在多种代码结构，才能实现各类复杂的数据计算。常用的代码结构有顺序结构、选择结构和循环结构。

2.6.1 顺序结构

顺序结构即按照语句的书写顺序从上到下、逐条语句地执行程序。执行时，排在前面的代码先执行，排在后面的代码后执行，执行过程中没有任何分支。顺序结构是最普遍的结构形式，也是选择结构和循环结构的基础。

2.6.2 选择结构

选择结构又称为分支结构，是根据“条件”来选择执行哪一分支中的语句，包括二分支和多分支，以及分支的嵌套。

2.6.2.1 if … then语句

选择结构中，if then 结构是最基础的一个。它只有条件表达式真时，执行的代码。

用if...then结构有条件地执行一个或多个语句有两种语法形式。

1.单行结构条件语句

单行结构条件语句是最基本的条件语句，其语法为：

	if 条件表达式 then 语句

条件表达式即可以任何计算数值的表达式，vba将这个值解释为true或false：为零的数值为false；而任何非零数值都被看作true。

该语句的功能为：若逻辑表达式的值是true，则执行then后的语句；若逻辑表达式的值是false，则不执行then后的语句，而执行下一条语句。

2．块结构条件语句

在if…then语句中，如果条件成立时需要执行多个操作，可将多个语句写在then后面，并用冒号:分隔。if…then语句还提供另外一种块结构的方法，可使执行多行代码的过程更清晰，其语法如下：

	if 条件表达式 then
	    语句1
	    语句2
	    ……
	end if

2.6.2.2 if … then … else语句

在if … then语句中，当条件为false时，不执行任何语句。若要求在条件为false时要执行另一段代码，可用if...then…else语句。if...then...else语句也有两种格式：单行和多行。单行的格式为：

	if 条件表达式 then 语句1 else 语句2

当“逻辑表达式”的值为true时，执行关键字then后面的“语句1”；当“逻辑表达式”的值为false时，执行关键字else后面的“语句2”。

多行条件语句将根据条件表达式的值来判断并执行其中一个语句块。语法格式如下：

	if 逻辑表达式 then
	   语句序列1
	else
	   语句序列2
	end if

2.6.2.3 iif函数

iif函数可用来执行简单的条件判断操作，它是if…then…else结构的简写版本，其语法格式如下：

	result=iif(条件表达式, true部分, false部分)

变量result保存函数的返回值。“条件表达式”为判断的条件，当条件为true时，iif函数返回“true部分”；当条件为false时，iif函数返回“false部分”。

2.6.2.4 if … then … elseif语句

在很多情况下，可能需要判断几个不同的条件，并根据不同条件执行不同的语句。这时可使用if…then…elseif语句来对多个不同条件进行判断，并在多个语句块中选择执行其中的一个，其语法格式如下：

        if 条件表达式1 then
            语句序列1
        elseif 条件表达式2 then
            语句序列2
        elseif 条件表达式3 then
            语句序列3
            ……
        else
            语句序列n
        end if

在以上结构中，可以包括任意数量的elseif子句和条件，elseif子句总是出现在else子句之前。

vba首先判断“条件表达式1”的值。如果它为false，再判断“条件表达式2”的值，以此类推，当找到一个为true的条件，就会执行相应的语句块，然后执行end if后面的代码。如要所有“逻辑表达式”都为false，且包含else语句块，则执行else语句块。

2.6.2.5 select case语句

在if...then分支语句中，总是可以添加更多的elseif块，但是，当每个elseif块都将相同的表达式比作不同的数值时，这个结构编写起来很乏味，也不易阅读。在这种情况下可以用多分支选择结构select case语句。

select case语句的功能与if...then...else语句类似，但对多重选择的情况，select case语句可使代码更易读。

select case在结构的开始处理一个测试表达式并只计算一次，然后，vba将表达式的值与结构中的每个case的值进行比较，如果相等，就执行与该case相关联的语句块，执行完毕再跳转到end select语句后执行。其语法格式如下：

	select case 测试表达式
	  case 表达式列表1
	        语句序列1
	  case 表达式列表2
	        语句序列2
	          ……
	  case else
	        语句序列n
	end select

其中“测试表达式”可以是数值型或字符型的表达式，通常是一个数值型或字符型的变量。表达式列表可以是一个或几个值的列表。如果在一个列表中有多个值，就用逗号将各个值分隔开。每一个语句序列中含有零个或多个语句。如果不止有一个case与测试表达式相匹配，则只对第一个匹配的case执行与之相关联的语句块；如果表达式列表中没有一个值与测试表达式相匹配，则vba执行case else子句（此项可选）中的语句。

2.6.2.6 分支结构的嵌套

在一个分支结构语句中还可以包含另一个分支结构语句，称为分支结构的嵌套。

2.6.3 循环结构

在vba中，循环结构用于多次重复执行同一段代码。重复次数通过特定数字或特定条件控制。

通过控制循环过程中特定变量，循环结构可执行复杂的重复任务。

2.6.3.1 do … loop循环

用do循环重复执行一语句块，且重复次数不定。do…loop语句有4种演变形式，但每种都需要计算条件表达式的值，以决定是否继续执行。在do循环中可以使用exit do语句中途退出该循环。

1.do while…loop循环
do while语句属于先测试循环条件的do…loop语句，其语法格式如下：

	do while 条件表达式
	    语句序列1
	  [exit do]
	  [语句序列2]
	loop

在do while和loop之间的语句称为循环体。

当vba执行这个do循环时，首先判断条件表达式：如果为false（或零），则跳过所有语句，执行loop的下一条语句；如果为true（或非零），则执行循环体，当执行到loop语句后，又跳回到do while语句再次判断条件。在循环体中如果包含有exit do语句，则当执行到exit do语句时，马上跳出循环，执行loop的下一条语句。

这种形式的循环体可能执行零次或多次。只要条件表达式为true或非零，循环就会重复执行。如果逻辑表达式最初就为false，则不会执行循环语句。

2.do…loop while循环
do...loop while语句属于后测试循环条件的do…loop语句，该结构先执行循环体中的语句，然后再进行条件判断。这种形式的循环体至少执行一次，其语法格式如下：

	do
	    语句序列1
	  [exit do]
	  [语句序列2]
	loop while 条件表达式

3.do until…loop循环

do until…loop语句为先测试结束条件的do…loop语句，其语法形式如下：

	do until 条件表达式
	    语句序列1
	    [exit do]
	    [语句序列2]
	loop

这种形式与do while…loop类似，不同的是当条件表达式的值为false时才执行循环体，否则退出循环。这种形式的循环体可能执行零次或多次。

4.do…loop until循环

do…loop until语句是后测试结束条件的do…loop语句，其语法形式如下：

	do
	    语句序列1
	    [exit do]
	  [语句序列2]
	loop until 条件表达式

这种形式与“do…loop while”类似，不同的是当条件表达式的值为false时才执行循环体，否则退出循环。这种形式的循环体至少能被执行一次。

2.6.3.2 while … wend循环

while…wend循环语句的功能与do…while循环相同，是从basic的早期版本中保留下来的语句，vba保留它是为了向后兼容，其语法格式如下：

	while 条件表达式
	    循环体
	  ……
	wend

如果“条件表达式”为true，则所有的“循环体”语句都会执行，一直执行到wend语句，然后再回到while语句，并再一次检查“逻辑表达式”的值，如果还是为true，则重复执行；如果不为true，则程序会从wend语句之后的语句继续执行。

2.6.3.3 for … next循环

for…next语句以指定次数来重复执行循环体。与do循环不同，for循环使用一个叫做计数器的变量，每重复一次循环之后，计数器变量的值就会增加或者减少。在for循环中可以使用exit for语句随时退出该循环。for循环的语法格式如下：

	for 循环变量=初始值 to 终值 [step 步长值]
	    语句序列1
	    [exit for]
	  [语句序列2]
	next [循环变量]

其中，步长值可正可负。如果步长值为正，则初始值必须小于或等于终值才能执行循环体，否则退出循环；如果步长值为负，则初始值必须大于或等于终值，这样才能执行循环体。如果没有设置step，则步长值默认为1。

vba执行for循环时的过程如下所述。
1)将初始值赋值给循环变量。

2)判断循环变量是否超过终值，若为真（true），退出循环，执行next的下一语句。这里的“超过终值”有两种意思：若步长值为负数时，超过就是循环变量的值小于终值；而当步长值为正数时，超过就是循环变量的值大于终值。

3)执行循环体。

4)循环体执行完后到达next语句时，循环变量累加上步长值。

5)重复步骤2)到步骤4)。

for循环一般都可计算出循环体的执行次数，计算公式如下：

循环次数=[(终值-初值)/步长值]+1

中括号[ ]表示取整。

2.6.3.4 循环的嵌套

与分支结构类似，循环结构也可进行嵌套，即将一个循环放置在另一个循环中。vba允许在同一过程里嵌套多种类型的循环。

2.6.3.5 goto语句

使用goto语句，可无条件地将程序代码跳转到指定的行去执行。vba中保留goto语句是为了保持与早期的basic版本兼容。goto语句的语法格式如下：

	goto 行号/标号

注：go to只能跳到它所在过程中的行。

要使用goto语句，首先需用了解vba中语句的行号和标号。在早期的basic语言中，每一行程序都有一个行号，行号按从小到大的顺序排列，例如：

	sub 使用do循环删除为0的行()
	10   dim i as integer
	20   i = 1
	30   with sheets("sheet2")
	40   do while i <= 100
	50       if .cells(i, 2) = 0 then
	60          .cells(i, 2).entirerow.delete
	70       end if
	80       i = i + 1
	90   loop
	100 end with
	end sub

在vba中，执行这样的代码也不会出错。为程序添加行号的目的就是方便使用goto语句跳转到相应的语句去执行。

随着结构化程序设计方法的使用，使用goto语句跳转的方式已经不常用了，也就不再需要为每行代码添加行号了。

为了使goto跳转到需要的地方，可在程序中添加标号。标号是以英文字母开头的一个标识符后加上一个冒号构成的。在程序代码中输入的标号始终是靠左对齐的。

例如，以下代码使用goto语句来进行循环操作，删除单元格为0的行：

	sub 使用goto语句删除为0的行()
	  dim i as integer
	  i = 1
	line1:
	  with sheets("sheet2")
	      if .cells(i, 2) = 0 then
	          .cells(i, 2).entirerow.delete
	      end if
	      i = i + 1
	      if i <= 100 then goto line1
	  end with
	end sub

不建议在程序中使用太多的goto语句，因为使用goto语句会使程序代码不容易阅读及调试。应尽可能使用结构化控制语句（do…loop，for…next，if…then…else和select case）。

2.7 数组

对于大量有序的数据，可以使用数组对其进行存储和处理。

在vba中，数组中各元素可以是相同的数据类型，也可以是不同的数据类型。

2.7.1 声明数组

计算机中数组占用一片连续的内存空间。在使用之前，必须先对数组进行声明（定义），让计算机系统为其分配一片连续的内存空间。

声明数组变量必须为数组指定大小。若数组的大小被指定，则它是一个大小固定的数组；若程序运行时数组的大小可以被改变，则它是一个动态数组。

2.7.1.1 声明一维数组

有两种方法声明大小固定的一维数组。

方法1：

dim 数组名(上界) as 数据类型

方法1与其他程序设计语言定义数组的格式相同，只给出数组下标的上界而省略下标的下界（默认为0），即数组的下标从0开始至定义的上界。
例如，定义一个名为myarray 的数组，共有11 个元素，分别为myarray(0)，myarray(1)…myarray(10)：

dim myarray(10) as string

如果希望数组下标从1开始，可以通过option base语句来设置：

option base 1

注：使用该语句指定的数组下标的默认下界只能为0或1。该语句只能出现在用户窗体或模块的声明部分，不能出现在过程中，且必须放在数组定义之前。

方法2：

dim 数组名(下界 to 上界) as 数据类型

方法2可定义数组的下标下界为任意值。
例如，定义一个数组myarray，共有12 个元素，分别为myarray(-1)，myarray(0)，myarray(1)…myarray(10)：

dim myarray(-1 to 10) as string

2.7.1.2 声明二维数组

二维数组的声明方式与一维数组类似，不同的是需要设置两个上下标变量。

方法1（只定义数组上界）：

dim 数组名(第1维上界, 第2维上界) as 数据类型

方法2（同时定义上下界）：

dim 数组名(第1维下界 to 第1维上界, 第2维下界 to 第2维上界) as 数据类型

声明多维数组的格式与二维数组类似，每一维都使用逗号隔开即可。但需要注意的是，定义大数据量的数组将占用很大的内存空间。

2.7.2 默认数组

默认数组，即数据类型为variant（默认类型）的数组。使用默认数组的好处是可以让每个数组元素保存一个不同类型的值，得到一种混合状态的数组。

vba中定义默认数组语法如下：

dim 数组名(上界)

等同于：

dim 数组名(上界) as variant

2.7.3 动态数组

动态数组是指在程序运行时大小可以改变的数组。在声明动态数组时，可使用变量来设置下标。

声明动态数组一般分两个步骤：

1. 在用户窗体、模块或过程中使用dim或public声明一个没有下标的数组（不能省略括号）；
2. 在过程中用redim语句重新定义该数组的大小。
   redim语句在过程级别中使用，用于为动态数组变量重新分配存储空间。其语法格式如下：

redim [preserve] 数组名(下标) [as 数据类型]

可使用redim语句反复改变数组的元素及维数的数目，但是不能在将一个数组定义为某种数据类型之后，再使用redim将该数组改为其他数据类型，除非是variant所包含的数组。

在默认情况下，使用redim语句重定义数组的维数和大小时，数组中原来保存的值将全部消失。

如果使用preserve关键字，当改变原有数组最后一维的大小时，可以保持数组中原来的数据。同时，只能重定义数组最后一维的大小，并且不能改变维数的数目。

2.7.4 数组的基本操作

声明一个数组后，就可以对数组或数组中的元素进行操作了。操作通常包括数组的初始化、数组元素的复制及数组的删除等。

2.7.4.1 数组的初始化

在vba中，创建数组后将自动初始化数组中的每个元素：对于数值型的数组，每个元素都将清零；如果是字符串型的数组，每个元素将初始化为空字符串。

而如果是重定义动态数组，并且使用了preserve关键字，则不会对已有元素进行初始化，而只对新增加的元素进行初始化。

对数组元素的初始化一般使用循环语句来进行操作，可让用户逐个输入数组的初始值；也可按一定的规则读取工作表单元格中的值来对数组赋初始值；还可使用array函数来为数组元素赋值。

1.用户逐个输入数组的初始值

例如，以下代码将反复显示输入框要求用户依次输入10个数组元素的初始值，并保存到对应的数组元素中：

	for i = 1 to 10
	  myarray(i) = inputbox("请输入数组的第" & i & "个元素的值")
	next

注：inputbox函数返回的是字符串类型。如果数组定义为数值型，还需使用相关的函数将用户输入的内容进行转换，如用val函数将字符串转换为数值，也可以使用如ccur、cdate、cdbl、cint等相关函数进行转换。

2.读取工作表单元格中的值来对数组赋初始值

由于工作表就相当于一个二维数组，每个单元格就是二维数组中的一个元素。使用工作表中某部分单元格为数组赋初值时，可通过两个循环的嵌套完成。

例如，以下代码使用工作表单元格中的数据来为数组元素赋初始值：

	sub arrayinit()           '使用工作表单元格中的数据来为数组元素赋初始值
	  dim myarray(5, 5)
	  dim i as integer, j as integer
	  for i = 1 to 5
	      for j = 1 to 5
	          myarray(i, j) = worksheets("sheet2").cells(i, j)
	      next j
	  next i
	end sub

3.使用array函数来为数组元素赋值

array函数的语法如下：

数组变量名 = array(数据集)

其中，“数组变量名”是预先定义的数组名，后面不跟括号；array函数中的“数据集”是由一些常数构成的数据集合，各值之间用逗号分开。例如：

	sub arrayinit1()   '使用array函数初始化数组
	  dim myarray, i as integer
	  myarray = array("星期日", "星期一", "星期二", "星期三", "星期四", "星期五",
	"星期六")
	end sub

执行上述代码，最终得到myarray(0)=“星期日”、myarray(2)=“星期一”…myarray(6)=“星期六”。

注：注因为array函数的返回值为variant类型，所以在使用array函数给数组变量赋初值之前，定义数组时只能将其定义为variant类型，且不能设置其下标，否则将显示“不能给数组赋值”的错误提示。

2.7.4.2 数组元素的复制

单个的数组元素可像普通变量一样进行访问和赋值。因此，要将一个数组中的值复制到另一个数组时，使用for循环语句将数组元素逐个元素复制即可：

	sub 数组元素的复制()
	  dim myarray1(5) as integer, myarray2(5) as integer
	  dim i as integer
	  for i = 1 to 5
	      myarray1(i) = i   '将myarray1初始化为1~5
	  next
	  for i = 1 to 5
	      myarray2(i) = myarray1(i)   '将myarray1中的元素对应复制到myarray2中
	  next
	end sub

在以上代码中，如果将数组myarray2声明为一个variant变量，那么通过一条语句就能将myarray1中的所有元素复制到myarray2中：

	sub 数组元素的复制()
	  dim myarray1(5) as integer, myarray2 as variant
	  dim i as integer
	  for i = 1 to 5
	      myarray1(i) = i
	  next
	  myarray2 = myarray1    '将数组元素保存到variant变量中
	end sub

通过myarray2=myarray1语句赋值后，变量myarray2将保存一个数组变量。可使用myarray2(1)、myarray2(2)的形式访问数组中每个元素的值。

2.7.4.3 数组的清除

对于静态数组，当创建完成后，其内存空间也分配完成，数组的大小将不能再改变。

有时可能需要清除数组的内容或对数组重新定义，可使用erase语句重新初始化大小固定的数组的元素，并释放动态数组的存储空间。其语法格式如下：

	erase 数组名1, 数组名2, … …

erase语句根据静态数组还是动态数组来采取完全不同的行为：

• 静态数组
  • 固定数值数组：erase语句将每个元素设为0
  • 固定字符串数组(长度可变)：erase语句将每个元素设为零长度字符串(“”)
  • 固定字符串数组(长度固定)：erase语句将每个元素设为0
  • 固定 variant 数组：erase语句将每个元素设为 empty
  • 用户定义类型的数组：erase语句将每个元素作为单独的变量来设置
  • 对象数组：将每个元素设为特定值 nothing
• 动态数组：erase语句将删除整个数组结构并释放动态数组所使用的内存。在下次引用该动态数组之前，程序必须使用redim语句来重新定义该数组变量的维数。

简单来说，静态数组在使用erase语句后仍然存在，只是其内容被清空；而动态数组使用erase语句后即不存在了。

2.7.4.4 数组相关函数

vba中操作数组的主要有5个函数：array、isarray、erase、lbound和ubound。

1.检测变量是否为数组

isarray函数可检查指定的变量是否为一个数组：如果指定变量是一个数组，返回值为true，否则返回false。对于包含数组的variant表达式来说，isarray很常用。

	dim myarray(1 to 5) as integer, yourarray, mycheck    ' 声明数组变量
	yourarray = array(1, 2, 3)    ' 使用数组函数
	mycheck = isarray(myarray)    ' 返回 true
	mycheck = isarray(yourarray)    ' 返回 true

2．获得数组下标的范围

lbound函数和ubound函数可获得数组下标的下界和上界。其语法格式为：

	lbound(数组名[, 维数])
	ubound(数组名[, 维数])

如果省略“维数”参数，表示返回一维的下标下界或上界。

例如，定义数组：

	dim a(1 to 100, 0 to 3, -3 to 4)

则使用lbound函数的返回值分别为：

	lbound(a, 1)    ' 返回值为1
	lbound(a, 2)    ' 返回值为0
	lbound(a, 3)    ' 返回值为-3

则使用ubound函数的返回值分别为：

	ubound(a, 1)    ' 返回值为100
	ubound(a, 2)    ' 返回值为3
	ubound(a, 3)    ' 返回值为4

2.8 过程

过程是指由一组完成指定任务的vba语句组成的代码集合。在vba中，可执行的代码都必须放置在过程中。

2.8.1 过程的分类

vba中的过程可分为事件过程、属性过程和通用过程。

2.8.1.1 事件过程

事件是某个特定的时刻所发生的事情，它是对象状态转换过程的描述。事件没有持续时间，是瞬间完成的。

事件过程是当发生某个事件（如单击、双击）时，对该事件做出响应的程序段。在vba中，可以激发事件的用户动作包括切换工作表、选择单元格、单击鼠标等几十种事件。当事件发生时，将执行包含在事件过程中的代码。如果用户没有定义某事件所调用的过程，那么当发生该事件时就不会产生任何响应。

事件既可以由用户动作（如单击鼠标、按键等）产生，也可以由程序代码或系统产生（如计时器定时产生的事件）。编写事件响应代码是在“代码编辑器”中进行的，“代码编辑器”的右边有一个事件列表，这个事件列表从属于左边的控件对象，当左边控件列表中的控件改变后，右边的事件列表也会发生变化。

2.8.1.1.1 事件分类

excel提供了非常多的事件，主要分为以下几类。

1. 工作簿事件：工作簿事件发生在特定的工作簿中如open（打开工作簿）、beforeclose（关闭工作簿之前）和sheetactivate（激活任何一张表）等。工作簿事件的代码必须在thiswork对象代码模块中编写。
2. 工作表事件：工作表事件发生在特定的工作表中，例如activate（激活工作表）、change（更改工作表中的单元格）和selectionchange（工作表上的选定区域发生改变）等。工作表事件的代码必须在对应工作表的代码模块中编写。
3. 窗体、控件事件：新建的用户窗体及窗体上的控件也可响应很多事件，例如click（单击）、change（控件内容更改）等，这类事件的代码必须编写在相应的用户窗体代码模块中。
4. 图表事件：图表事件针对某个特殊的图表产生如select（选中了图表中的某个对象）和serieschange （改变了系列中的某个数据点的值）。
5. 不与对象关联的事件：不与对象关联的事件只有两个，分别是ontime和onkey，根据时间和按钮来产生这两个事件。

2.8.1.1.2 编写事件程序

以对工作簿的open事件编写处理代码为例，步骤如下：

1. 在excel环境下按“alt+f11”组合键打开visual basic编辑器。
2. 在左侧的“工程资源管理器”窗口中列出了当前工程项目中的excel对象，双击其中的“thisworkbook”对象，将在右侧打开代码编辑器。
3. 在代码窗口左侧对象下拉列表框中选择对象。
4. 选择好对象“workbook”后，在代码窗口右侧的事件下拉列表框中可看到出该对象的事件列表。
5. 选择好对象和事件后，系统自动生成事件过程的外部结构。在事件过程结构中编写响应该事件的代码即可。

2.8.1.2 属性过程

在vba中，除了模块、用户窗体外，还提供了类模块。类模块向开发人员提供了创建和操作自己的对象类的功能。

在“类模块”中设置类的属性值时，可通过“属性过程”来完成。

2.8.1.2.1 类

在vba中，有各种各样的对象如workbook、worksheet和range等，这些对象也都是通过相应的类来创建的。例如：

	dim rnguser as range '定义了一个对象变量rnguser，该变量存储对象range的引用

在这里，range是vba内部定义好的一个类（标准类）。

2.8.1.2.2 类的作用

vba提供类模块功能，让开发者也可以根据需要定义自己的类。

使用类模块编写代码，可以使程序更易管理、维护，也更利于大型应用程序的开发。

1．创建自定义对象

类模块可以用于在应用程序中建立和使用自己的对象类型。在应用程序开发过程中可以发现，很多系统都要使用到相似的功能。这时可将已有系统中的代码复制到新系统中，包括复制代码用到的数据，再逐行检查代码并进行修改。如果没有能保证代码与数据之间关系的措施，在操作过程中很可能会出现混乱，从而导致程序出现错误。

其实，将这些数据和程序包装在一个类中，在新的系统中使用该类创建一个对象，即可通过对象的属性、方法等来完成相应的功能。

2．封装复杂过程

使用类还可以将复杂的过程封装在类的内部，类的使用人员不需要知道类的实现过程，只需要熟悉类的属性、方法和事件即可。

2.8.1.2.3 类的预备知识

1．对象

对象是由类创建的一个实例，它是类的实体化。对象的引用和操作被划分为以下三个部分。

• 属性是指对象的特性。例如worksheet对象，有包含单元格的行数、列数等属性。
• 方法是指对象的某个操作。例如worksheet对象，有增加工作表、删除工作表等方法。
• 事件是指对象对外部动作的响应。例如单击worksheet对象的单元格时，会产生一个change事件；修改单元格内容时，会产生一个selectionchange事件。

2．变量的作用域

变量可以划分为过程级、模块级和全局变量。在类模块中，对变量作用域的理解要注意以下两点。

• 由于类是生成对象的模板，每一个对象相当于是类的一个副本，对象之间是相互独立的，因此，模块级的变量只作用于对象自身，对其他通过该类创建的对象不会起作用。
• 在类模块中使用public关键字声明的变量，通过该类生成的对象都可访问。

3．过程和函数

变量、过程和函数是标准模块中使用的最基本的构件。在类模块中，它们仍然是最基本和最重要的角色。过程和函数并无实质的区别，当需要返回值时，就使用function；如果不需要返回任何结果，可使用function，，也可使用sub。

过程、函数也有作用域，在标准模块中通过使用private和public关键字（可以省略public关键字，因为它是默认的）可以划分为模块级和全局级，以决定它是在当前的模块有效还是整个工程有效。

同变量一样，在类模块中使用public关键字的函数或过程才能被声明的对象调用。使用private关键字的函数或过程只能在类模块中进行调用。

2.8.1.2.4 创建类

1. 建立对象类
   在vba编辑器中选择“插入”→“类模块”命令，向工程插入一个类模块：
   
   在“属性”窗口中修改类的“(名称)”为“clsperson”：
   

2. 建立属性
   建立属性的方法有两种：
   a. 最简单的方法是在类模块中声明public变量作为对象的属性。这种方法的缺点是，类不能知道属性值何时被外部过程修改了，也就无法将属性值限定在一个有效的范围了。
   b. 另一种方法是使用property过程来定义属性值，这时外部过程修改属性值时，将执行property过程。在该过程中可以编写代码，对设置的值进行检查，控制其在一个规定的范围中。

   property过程有以下3种形式：

   • property let：这类过程用来设置类模块的属性值。

   • property get：这类过程用来读取类模块的属性值。

   • property set：这类过程用来设置对对象的引用。

     在使用property过程设置属性值时，类模块中的变量可声明为private类型，避免过程直接修改类模块中变量的值。

     创建属性时的3个步骤如下：

     ① 创建私有变量。在创建clsperson类时，需要在类模块的声明部分使用以下代码声明变量：

     private m_id as string     '编号
     private m_name as string   '姓名
     private m_sex as string    '性别
     private m_birthday as date '出生年月
     private m_company as string'工作单位
     

     ② 创建property get过程来获取对象的属性值。

     ③ 创建property let过程来设置上一步定义的私有变量的值。

3. 创建property get过程
   property get语句用来获取对象的属性值。其基本形式就是一个声明和一个主体。声明包括属性名和数据类型。每个属性值都需要创建一个property get过程。

   对于clsemp类，其4个属性值的property get过程代码如下：

   property get id() as string
     id = m_id                                    '返回编号
   end property
   property get pername() as string
     pername = m_name                             '返回姓名
   end property
   property get sex() as string
     sex = m_sex                                  '返回性别
   end property
   property get birthday() as date
     birthday = m_birthday                        '返回出生日期
   end property
   property get company() as string
   company = m_company                            '返回工作单位
   end property
   

4. 创建property let过程
   与property get过程相对应的就是property let过程。通过property let过程可让使用者改变对象的属性值。

   一般每个属性值都需要编写一段property let过程。如果对象的某个属性为只读，则不能定义property let过程。以下代码中没有定义id属性的property let过程，表示该属性为只读。

   property let pername(strname as string)
     m_name = strname                         '设置姓名属性
   end property
   property let sex(strsex as string)
     if strsex <> "男" and strsex <> "女" then
         exit property
     else
         m_sex = strsex                       '设置性别属性
     end if
   end property
   property let birthday(datbirthday as date)
     m_birthday = datbirthday                '设置出生日期属性
   end property
   property let company(strcompany as string)
   m_company = strcompany                    '设置工作单位属性
   end property
   

5. 创建对象类的方法
   除了属性之外，一般对象至少有一个方法。方法是对象可以执行的操作，使用方法可以操作对象类中的数据。

   在clsper类中创建两个方法，一个用于调换工作单位；

   public function exchangecom(strcompany as string) as boolean
   if strcompany <> "super公司" and strcompany <> "end公司" then
     exchangecom = false
     else
     m_company = strcompany
        exchangecom = true
     end if
   end function
   

6. 类模块的事件
   事件是对象可识别的动作，例如按钮对象可识别click事件。自定义类模块有initialize事件和terminate事件，这两个事件分别在类的实例初次创建时和最后一个指针释放或破坏时触发。可以用initialize事件设置对象类的默认属性值；用terminate事件进行销毁对象前的整理工作。

   在clsper类中，员工的编号不能通过property let过程设置（为只读属性），但可以在initialize事件中编写代码对其进行赋值。编写initialize事件代码的过程如下。

   （1）在类模块代码窗口的对象下拉列表中选择“class”，在事件下拉列表中选择“initialize”。
   （2）编写以下代码：

       private sub class_initialize()
         randomize
         m_id = int(10000 * rnd)                     '生成一个4位数
         m_id = format(m_id, "0000")                 '进行格式化处理
       end sub
   

   在上述代码中，通过随机函数rnd得到一个0～1之间的小数，再将其乘以10 000后取整，可得到一个4位数。如果位数小于4位，则使用format函数在前面加上0。

2.8.1.2.5 使用类模块创建对象

创建一个用户窗体，在窗体中使用clsperson类来管理人员资料。

1. 设计新增人员窗体

   设计一个新增人员窗体，可接收用户输入人员的相关数据，并将其保存到clsper对象类中。具体的操作步骤如下：

   ① 在vba编辑器中选择“插入”→“用户窗体”命令，向工程中增加一个用户窗体。

   ② 设置窗体的名称属性为“frmmain”，并向窗体中添加如下图所示的控件：
   
   ③ 在窗体模块的声明部分输入以下代码：

   dim person as new clsperson            '声明一个clsper对象
   public persons as new collection       '声明一个集合对象
   

   ④ 在窗体的initialize事件中调用过程disablebox，将窗体中的输入控件禁用，禁止用户输入数据：

   private sub userform_initialize()
   	call disablebox                    '调用过程禁止用户输入
   end sub
   

   ⑤ disablebox过程的代码即设置各控件的enable属性为false即可，enablebox则是设置为true：

    sub disablebox()
        txtname.enabled = false
        txtbirthday.enabled = false
        txtcom.enabled = false
        optman.enabled = false
        optwoman.enabled = false
   end sub
   
   sub enablebox()
       txtname.enabled = true
       txtbirthday.enabled = true
       txtcom.enabled = true
       optman.enabled = true
       optwoman.enabled = true
   end sub
   

   ⑥ 为“新增”按钮编写如下代码：

   private sub addperson_click()
   if addperson.caption = "新 增" then
       addperson.caption = "保 存"                  '更改按钮提示信息
       call enablebox
       txtname.value = ""
       txtbirthday.value = ""
       txtcom.value = ""
       txtname.setfocus
     else
       addperson.caption = "新 增"                  '更改按钮提示信息
       with person
         .pername = txtname.value               '姓名
         if optman then                         '性别
             .sex = optman.value
         else: .sex = optwoman.value
         end if
         if isdate(txtbirthday.value) then
           .birthday = cdate(txtbirthday.value))'出生日期
         else
           .birthday = dateserial(1900, 1, 1)   ' 默认值
         end if
         .company = txtcom.value                '工作单位
       end with
       persons.add person, person.pername       '将对象添加到集合中
       call disablebox                          '禁止用户录入
     end if
   end sub
   

   其中，单击“新增”按钮时，将窗体中的文本框等控件设置为允许输入状态，先清空原有数据，接受用户输入数据，同时将按钮的提示文字改为“保存”。
   单击“保存”按钮时，将窗体中输入的数据保存到emp对象的各个属性中，并将emp对象添加到emps集合对象中，同时修改按钮和文本框等控件的状态。

   ⑦ 当用户点击调整工作单位按钮时，弹出相应的窗体，代码如下：

   private sub adjust_com_click()
     frmcom.show                              '调整人员工作单位
   end sub
   

2. 设计调整员工部门窗体

   调整员工部门的窗体将调用emp对象的exchangedep方法来调整员工的工作部门。该窗体用于输入员工的姓名，以及调整后的部门。具体步骤如下：

   ① 在vba编辑器中选择“插入”→“用户窗体”命令，向工程中增加一个用户窗体。

   ② 设置窗体的名称属性为“frmcom”，并向窗体中添加如下图所示的控件：
   
   为“保存”按钮编写代码如下：

   private sub confirm_click()
       dim person as clsperson
       dim b as boolean
       b = false
       for each person in frmmain.persons
           if person.pername = txtname.value then
               person.exchangecom txtcom.value
               msgbox "人员姓名：“" & txtname.value & "”的新工作单位为：" & person.company
               b = true
           end if
       next
       if not b then
           msgbox "输入的人员姓名有误!"
       end if
   end sub
   

测试结果：

2.8.1.3 通用过程

有时在不同的事件过程中需要执行一段相同的代码，可以把这段代码独立出来，作为一个过程，这样的过程称为“通用过程”。

在vba中，通用过程又分为两类：sub（子程序）过程和function（函数）过程。

• sub过程：这类过程完成指定任务，执行结束后不返回值。
• function过程：这类过程完成指定的任务，并返回一个值供调用程序使用。

一般通用过程保存在vba的“模块”中，一个模块可以包含任意数量的过程，同时，一个vba工程可以包括任意多个模块。

2.8.2 定义sub过程

vba中有两种定义过程的方法：一种方法是使用窗体创建过程的结构，再在过程中编写相应的代码；另一种方法是在模块中直接输入代码来定义过程。

2.8.2.1 使用窗体创建sub过程

1. 在vba编辑器中选择“插入”→“过程”命令，打开“添加过程”对话框：
   

在这个对话框中，除了可以插入一个新的sub过程、function过程或属性过程，还可以设置public或private有效范围，并使得过程中所有的局部变量成为静态变量。

2. 在“名称”后的文本框中输入过程的名称，并在“类型”栏中选择“子程序”单选框，接着在“范围”栏中选中“公共的”单选框，设置过程为全局的（即在工程的各模块中都可以调用该过程），将在过程前面添加public关键字。还可根据需要选中下方的“把所有局部变量声明为静态变量”复选框，如果选中该复选框，将在过程名前面添加static关键字。
3. 单击“确定”按钮，vba将自动生成过程的结构代码：
   

2.8.2.2 使用代码创建sub过程

sub过程的结构如下：

	[private | public | friend] [static] sub 过程名 [(参数列表)]
	    [语句序列1]
	    [exit sub]
	    [语句序列2]
	end sub

过程由sub、end sub及它们之间的vba代码构成。其中在sub前面可加上限制过程作用域的关键字，主要有以下几个:

• private：表示只有在包含其声明的模块中的其他过程可以访问该sub过程。
• public：表示所有模块的所有其他过程都可访问这个sub过程。如果在sub前面省略关键字，则表示其为public。
• friend：只能在类模块中使用，表示该sub过程在整个工程中都是可见的，但对对象实例的控制者是不可见的。
• static：表示在调用时保留sub过程的局部变量的值。static属性对在sub之外声明的变量不会产生影响，即使过程中也使用了这些变量。

end sub语句标志着sub过程的结束。为了能正确运行，每个sub过程必须有一个end sub语句，当程序执行到该语句时就结束该过程的运行。另外，在过程中可以使用一个或多个exit sub语句直接退出过程的执行。

需要注意的是，sub过程的定义不能嵌套，即不能将过程的定义放在另一个过程中。

2.8.3 调用sub过程

在vba中，通过调用定义好的过程来执行程序。sub过程的调用分两种方式：一种是在vba代码中调用sub过程；另一种是在excel中以调用宏的方式来执行sub过程。

2.8.3.1 使用vba代码调用sub过程

在程序中调用sub过程有两种方式：一种是把过程名放在一个call语句中；另一种是把过程名作为一个语句来使用。

1. 用call语句调用sub过程
   用call语句可将程序执行控制权转移到一个sub过程或function过程中，在过程中遇到end sub或exit sub语句后，再将控制权返回到调用程序的下一行。call语句的语法格式如下：

   call 过程名(过程参数列表) '如果过程没有参数，可省略过程名后的括号
   

2. 将过程作为一个语句
   在调用过程时，如果省略call关键字，过程也可调用。与使用call关键字不同的是，如果过程有参数，这种调用方式必须要省略“参数列表”外面的括号。
   即：

   过程名 过程参数1, 过程参数2, ...
   

2.8.3.2 以宏方式调用sub过程

在vba中，可以将sub过程作为一个宏来调用。

1. 切换到excel工作界面。

2. 在工作表中任意位置插入并绘制一个按钮：
   

3. 在打开的“指定宏”界面中选择vba中写好的sub过程名称，并点击确定：
   

4. 点击该创建的按钮即运行相应的sub过程。

注：以宏方式调用sub过程无法给过程传递参数，因此需要用参数的过程不会显示在宏列表中。

2.8.4 传递参数

为了使过程更具有通用性，大多过程都需要设置参数。传递不同的参数给过程，能有不同的执行结果。

对于有参数的过程，在调用时必须将实际参数传递给过程，完成形参与实参的结合，过程再使用实参执行代码。

2.8.4.1 形参与实参的结合

形参即形式参数的简称，是在sub过程的定义中出现的变量名。因其没有具体的值，只是形式上的参数，所以称为形参。

实参即实际参数的简称，是在调用sub过程时传递给sub过程的值。在vba中实参可为常量、变量、数组或对象类的数据。

在vba中，形参与实参的结合有两种方式。

1. 按位置结合

   大多数程序语言调用子过程时都按位置结合形参与实参。

   按位置结合即调用sub过程时使用的实参次序必须与定义sub过程时设置的参数次序相对应。例如，使用以下代码定义sub子过程：

   sub test(arg1 as integer, arg2 as long, arg3 as string)
   ...
   end sub
   

   子过程中定义了3个参数。可使用以下语句调用该子过程：

   call test(1, 2, "abc")
   

2. 按命名参数方式结合

   形参与实参的另一种结合方式是按形参名称来进行的，即在调用sub过程时，输入形参的名称，将形参名称与实参用符号:=连接起来。与按位置结合方式不同，使用这种方式时，调用过程的参数位置可随意设置。
   例如，使用命名结合的方式调用上面定义的“test”子过程：

   call test(arg1:=1, arg3:="abc", arg2:=2)
   

2.8.4.2 传地址

在vba中，实参可通过两种方式将数据传递给形参，即传地址和传值。

传地址是vba默认的方式，在定义过程时，如果在形参前面有关键字byref，则该参数通过传地址的方式传递。传地址是指将实参变量的地址传递给形参，这让形参和实参都代表同一个内存区域。

例如：

    sub 传地址测试(byref a as integer)
      a = a + 1
      debug.print "子过程中的变量a=" & a
    end sub

由于sub过程不能返回运算结果，如果需要sub过程返回值时，可通过使用byref方式来定义形参就可将子过程的运算数据返回到调用程序中。

2.8.4.3 传值

传值就是将实参的值作为一个副本，赋值给形参，而不是传送实参的地址给形参。定义过程时，在形参的前面添加byval关键字，则该参数就按传值方式传递，否则用传地址方式传递。

使用传值方式传递参数时，传递的只是变量的副本。如果过程改变了形参的值，所做改变也只在过程内部起作用，不会影响到调用程序中变量的值。

例如：

    sub 传值测试(byval a as integer)
      a = a + 1
      debug.print "子过程中的变量a=" & a
    end sub

在程序中使用传地址方式比传值方式效率高，但是传地址方式中，形参不是一个真正的局部变量，有可能对程序产生不必要的影响。如无特殊需求，应尽量使用传值方式。

2.8.4.4 传递数组参数

数组作为在内存中的一片连续区域，也可作为一个参数传递给sub子过程进行处理。数组一般是通过传地址方式进行传递的。

例如，编写一个求数组中最大数的过程：

     sub 求最大数(a() as integer)
       dim i as integer, max as integer
       max = a(lbound(a))
       for i = lbound(a) to ubound(a)
           if a(i) > max then max = a(i)
       next
       debug.print "最大数:" & max
     end sub

在该过程中，将形参定义为一个数组。使用数组作为形参时，必须输入数组名并跟上一对空括号。对传递到过程的数组，应使用lbound函数和ubound函数获取其下标的下界和上界，接着程序才能遍历数组或对数组进行其他相关的操作。

2.8.5 可选参数和可变参数

在创建vba的过程时，除了可设置参数按地址或按值传递之外，还可以根据需要为过程设置可选参数和可变参数。

2.8.5.1 可选参数

通常情况下，一个vba过程中的形参数量是固定的，调用时提供的实参数量也是固定的。但在有的过程中，可能有必需收集信息和可选信息，例如收集顾客的信息时必须提供“姓名”、“性别”，而“身份证号码”则是可选的。

vba的过程可以通过对形参前面加上optional关键字来设置该形参为可选参数。在过程内部通过使用ismissing函数可测试调用程序是否传递了该可选参数。例如：

    sub 可选参数(strname as string, strsex as string, optional id)
      with worksheets("sheet2")
          .range("a2") = strname
          .range("b2") = strsex
          if not ismissing(id) then
              .range("c2") = id
          end if
      end with
    end sub

注：过程中可定义多个可选参数，但可选参数必须放在参数表的最后，而且必须是variant类型。

2.8.5.2 可变参数

无论是固定参数还是可选参数，在定义过程时都已经指定了参数的个数。在vba中，还可以定义可变参数，即参数的个数在定义时是未知的。

在定义过程的参数表时，在最后一个参数前面加上paramarray关键字，过程将接受任意个数的参数。例如，使用可变参数编写求和函数sum：

    sub mysum(inttotal as integer, paramarray intnum())
      dim i as integer, j as integer
      for i = lbound(intnum) to ubound(intnum)
          inttotal = inttotal + intnum(i)
      next
    end sub

该过程中，可变参数为一个数组。程序中使用lbound函数和ubound函数获得数组下标的上下界，然后进行累加，并将累加的结果保存在第一个参数中，用于返回给调用程序。调用以上子过程的代码如下：

    sub 调用可变参数()
      dim i as integer
      mysum i, 1, 2, 3, 4, 5, 6, 7, 8
      debug.print i
    end sub

程序中定义了一个变量i，用来获得子过程运算的结果。参数传递时，将参数i用传地址方式传递给“mysum”子过程的形参inttotal，将后面的“1、2、3、4、5、6、7、8”作为一个数组传递给形参intnum。

注：paramarray只能用于参数列表的最后一个参数，指明最后这个参数是一个variant元素的optional数组。另外，paramarray关键字不能与byval、byref或optional一起使用。

2.9 函数

2.9.1 函数与过程

function函数和sub过程都属于vba的通用过程。

function函数和sub过程的相同点有：

• 都是构成vba程序的基本单位。
• 都可用public、private等关键字设置过程的作用区域。
• 都可接收参数，参数的设置相同（如传递方式、可选参数、可变参数等）。

function函数和sub过程的不同点有：

• sub过程不能返回一个值，而function函数可以返回一个值，因此function函数可以像excel内部函数一样在表达式中使用。
• sub过程可作为excel中的宏来调用，而function函数不会出现在“选择宏”对话框中，要在工作表中调用function函数，可像使用excel内部函数一样。
• 在vba中，sub过程可作为独立的基本语句调用，而function函数通常作为表达式的一部分。

2.9.2 定义函数

function函数的创建方法与sub过程的方法类似。在使用function函数时，一般需要使用一个变量来接收返回值。

2.9.2.1 创建函数

创建函数有两种方法：

方法1：

通过对话框和手工输入代码。通过对话框创建函数的方法与创建sub过程相似，在vba编辑器中选择“插入”→“过程”命令，打开“添加过程”对话框，接着在“添加过程”对话框在“类型”栏中选择“函数”单选框，输入函数名称即可创建函数的结构。

方法2：

输入代码创建function函数，function结构如下：

    [public | private | friend] [static] function 函数名 [(参数列表)] [as 返回类型]
          语句序列1
          函数名 = 表达式1
        exit function
          语句序列2
          函数名 = 表达式2

    end function

与sub过程不同的是，function函数在声明函数名的第一行使用“as返回类型”定义函数的返回值类型；在函数体内，通过给函数名赋值来返回计算结果。

如果在函数体内没有赋值返回计算记过语句，则该函数返回一个默认值：数值函数返回0；字符串函数返回空字符串。

例如，使用function函数实现数组求和功能：

    function mysum(paramarray intnum()) as long
      dim i as integer, j as long
      for i = lbound(intnum) to ubound(intnum)
          j = j + intnum(i)
      next
      mysum = j
    end function

2.9.2.2 调用函数

调用function函数也有两种方式：一种是在工作表的公式中使用；另一种是从vba的另外一个过程里调用。

1．在工作表中调用函数

自定义function函数和系统内置函数一样，可在excel工作表的公式中进行引用。如果不知道function函数的名称或它的参数，可以使用“插入函数”对话框帮助用户向工作表中输入这些函数。例如，要在工作表中引用“mysum”函数的过程如下。

① 在excel窗口中，单击选择一个单元格。

② 在功能区“公式”选项卡的“函数库”组中，点击“插入函数”按钮，将打开“插入函数”对话框：

③ 选择“用户定义”类别，并点击“确定”：

④ 在“函数参数”对话框可输入函数所需要的参数，并点击“确定”即可：

2．在vba代码中调用函数

function函数与内部函数没有什么区别，只不过内部函数vba由系统提供，而function函数是由用户自己定义的。因此，可以像使用vba内部函数一样来调用function函数。例如，以下代码调用mysum函数，并将计算结果保存到t中：

    sub test1()
      dim t as long
      t = mysum(1, 3, 8, 10, 12)
      debug.print t
    end sub

还可将function函数作为表达式的一部分，使用其返回值参加表达式的运算，例如：

    t = t + mysum(1, 3, 8, 10, 12) * 3

3 excel应用程序开发流程

3.1 需求分析

在进行excel应用程序开发时，首先需要准确了解用户的需求，需求分析的目的是确定需要完成哪些工作。

需求分析阶段的主要任务如下：

• 功能需求：给出应用程序必须完成的所有功能。
• 环境需求：用户的计算机硬件环境、软件环境和excel的版本等。
• 界面需求：应用程序的用户界面是直接面对用户的，界面设计是用户能否方便、快捷地操作应用程序的关键之一。在需求分析阶段，应提出界面的需求。
• 安全保密需求：对客户信息的保密要求应在本阶段进行计划。
• 用户技术层次：在需求分析阶段，了解用户的技术层次，可为应用程序的开发提供一些辅助信息。

3.2 界面设计

在excel中进行界面设计的方式主要有以下3种：

1. 在工作表中添加控件
   在较简单的应用程序中（只需要调用少数几个宏过程），可向工作表中添加按钮或其他控件，接着与宏过程进行绑定即可：
   
   
   
2. 用户窗体
   用户界面是应用程序的一个重要组成部分。在excel的应用程序中，用户窗体作为应用程序的用户界面部分，将用户的操作和excel工作表中的数据隔离开。
   在vba编辑器中插入一个用户窗体：
   
   使用工具箱（视图→工具箱打开）中的控件设计窗体：
   
3. 自定义功能区
   功能区是从excel 2007起新增加的组件，取代了以往版本的菜单和工具栏，可使用xml代码自定义功能区。
   

3.3 代码设计

将用户界面设计好以后，接下来就需要编写界面中各部分的事件代码（如用户窗体中的按钮、功能区中的按钮等）。

在excel中设计vba应用程序时，界面设计和代码设计一般是交替进行的，即设计好一个界面后就编写相应的代码。有时也可先录制修改好宏代码，再和工作表或用户窗体中的按钮进行绑定。

3.4 帮助系统

在windows应用程序中提供了在线电子文档的帮助系统，excel也可以制作这种帮助系统。
对于小型应用系统，一般不提供帮助系统；但对于一个大型应用系统，提供一个好的帮助系统可让用户更快地理解系统，更快地熟悉系统的功能。

3.5 系统测试

在创建了应用程序之后，必须对其进行测试，测试和调试应用程序所花费的时间可能与开发系统的时间同样多。

对于一个完成开发的应用程序，在设计测试数据时，应尽可能多地考虑到各种不同的情况：不但要使用正常的合乎逻辑的数据去测试应用程序的功能性，还应使用一些可能导致应用程序出错的数据去测试应用程序的健壮性。

在设计测试数据的同时应编写出测试数据的结果，并与应用程序进行实测时得到的数据进行对比，如果结果相同，则通过测试；否则，应检查并修改应用程序。

3.6 应用程序发布

通过测试后的应用程序就可以发布给最终用户使用了。在发布时需要注意以下3个问题:

1. excel版本：如果是在excel特定版本环境下开发的应用程序，并使用了该特定版本的一些新功能，就要求用户使用该excel的特定版本。
2. 动态链接库：如果应用程序中使用了activex控件，则需要考虑是否要将包含该activex控件的dll文件（或ocx文件）包含在应用程序中予以发布。
3. 辅助文件：在一个大型的应用程序中，有时可能还会使用到其他辅助文件（如图片文件、数据库文件和帮助文件等），需要将这些文件包括在发布文件中，并且最好将其发布到其他盘符中进行测试，以检查在vba代码中是否使用了绝对路径来引用相关的文件。

4 常用功能

• 待完成