批处理系统管理之6 - 用户和localgroup组篇_Dos/bat

对于 windows 系统管理员来说，经常遇到的操作可能包括：

进程
服务
注册表
任务计划
防火墙
网络
用户和组
共享
ftp

1、基本命令实例

# 创建本地组 bathomeadmins

net localgroup bathomeadmins /add /comment:"the group of administrators"

# 创建本地组 bathomeusers

net localgroup bathomeusers /add

# 添加组的描述

net localgroup bathomeusers /comment:"the group of users"

# 删除组的描述

net localgroup bathomeusers /comment:""

# 创建本地用户 batadmname1 密码为 batadmpass1

net user batadmname1 batadmpass1 /add

# 创建本地用户 batusrname1 密码为 batusrpass1

net user batusrname1 batusrpass1 /add

# 创建本地用户 batusrname2 密码为 batusrpass2

net user batusrname2 batusrpass2 /add

# 把用户添加到一个组

net localgroup bathomeadmins batadmname1 /add
net localgroup bathomeusers batusrname1 /add
net localgroup bathomeusers batusrname2 /add

# 查看一个组里面有哪些用户

net localgroup bathomeadmins
net localgroup bathomeusers

# 从组里面删除一个用户

net localgroup bathomeusers batusrname2 /delete

# 删除本地组

net localgroup bathomeadmins /delete
net localgroup bathomeusers /delete

# 查看一个用户属于哪些组

net user batadmname1 | findstr /i /b "本地组成员"
net user batusrname1 | findstr /i /b "本地组成员"

# 查看用户列表

net users
wmic useraccount get name /value | findstr "="

# 查看某个用户的详细信息

net user batadmname1
wmic useraccount where name='batadmname1' get * /value

# 添加用户的描述

net user batadmname1 /comment:"the administrator user"

# 删除用户的描述

net user batadmname1 /comment:""

# 设置一个用户的全名

net user batadmname1 /fullname:"guan liyuan"

# 更改用户的密码

net user batadmname1 batadmpassnew

# 把用户的密码更改为空

net user batadmname1 ""

# 禁用一个用户

net user batadmname1 /active:no

# 启用一个用户

net user batadmname1 /active:yes

# 设置用户可以登录的时间为周一到周五早九晚六

net user batadmname1 /time:m-f,09:00-18:00

# 设置用户随时可以登录

net user batadmname1 /time:all

# 删除一个用户

net user batusrname2 /delete

# 获取某个用户的sid

wmic useraccount where name='batusrname1' get sid /value

# 设置某个用户下次登录须修改密码

net user batusrname1 /logonpasswordchg:yes

# 取消某个用户下次登录须修改密码

net user batusrname1 /logonpasswordchg:no

# 设置某个用户的密码永不过期

wmic useraccount where name='batusrname1' set passwordexpires=false

# 设置某个用户不能更改密码

wmic useraccount where name='batusrname1' set passwordchangeable=false

net user batusrname1 /passwordchg:no

# 设置某个用户可以更改密码

wmic useraccount where name='batusrname1' set passwordchangeable=true

net user batusrname1 /passwordchg:yes

# 更改用户名

wmic useraccount where name='batusrname1' call rename batusrnamenew

2、批处理脚本实例

2.1 bat + net user 导出用户详细信息

@echo off
cd /d "%~dp0"
(for /f "skip=4 tokens=1-3" %%a in ('net user ^| findstr /v /i "命令成功完成。"') do (
    if "%%a" neq "" (
        net user %%a
        if "%%b" neq "" (
            net user %%b
            if "%%c" neq "" (
                net user %%c
            )
        )
    )
))&gt;"userdetail_1.txt"

2.2 bat + wmic + net user 导出用户详细信息

@echo off
cd /d "%~dp0"
(for /f "tokens=2 delims==" %%a in ('wmic useraccount get name /value') do (
    for %%b in (%%a) do (
        net user %%b
    )
))&gt;"userdetail_2.txt"

2.3 bat批量创建用户并加入指定组

把待创建的用户名和待加入的组按照下面的格式写入文件userlist.txt

;============================================================
;第一列: 用户名
;第二列及后面的列: 用户组
;每列之间以英文逗号分隔（逗号左右两侧不要有空格）
;每个组名左右两侧添加英文双引号（不要有多余空格）
;============================================================
batadm1,"administrators","remote desktop users"
batadm2,"remote desktop users"
batusr1,"remote desktop users","power users"
batusr2,"remote desktop users"

执行脚本createuser.bat

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "filepass=userpass.txt"
&gt;"%filepass%" echo ;username  password
for /f "tokens=1* delims=," %%a in ('type "userlist.txt"') do (
    call :getpass
    &gt;&gt;"%filepass%" echo %%a  !passstr!
    echo net user %%a !passstr! /add
    net user %%a !passstr! /add
    for %%c in (%%b) do (
        echo net localgroup %%c %%a /add
        net localgroup %%c %%a /add
    )
)
pause
goto :eof
:getpass
set "passlen=11"
set /a loopnum=passlen/3+3
set "passstr="
for /l %%i in (1,1,%loopnum%) do (
    call :getrand passstr
)
set passstr=!passstr:~1,%passlen%!
goto :eof
:getrand
set "str1=abcdefghijklmnopqrstuvwxyz"
set "str2=abcdefghijklmnopqrstuvwxyz"
set "str3=0123456789"
set /a x=%random%%%26
set /a y=%random%%%26
set /a z=%random%%%10
set "passstr=!passstr!-!str1:~%x%,1!!str2:~%y%,1!!str3:~%z%,1!"
goto :eof

创建用户之后随机生成的密码自动写入userpass.txt